Perl version

Modules

  • ABCDE
  • FGHIL
  • MNOPS
  • TUX

perllol

Perl 5 version 10.1 documentation
Recently read

perllol

NAME

perllol - Manipulating Arrays of Arrays in Perl

DESCRIPTION

Declaration and Access of Arrays of Arrays

The simplest thing to build is an array of arrays (sometimes imprecisely called a list of lists). It's reasonably easy to understand, and almost everything that applies here will also be applicable later on with the fancier data structures.

An array of an array is just a regular old array @AoA that you can get at with two subscripts, like $AoA[3][2] . Here's a declaration of the array:

  1. # assign to our array, an array of array references
  2. @AoA = (
  3. [ "fred", "barney" ],
  4. [ "george", "jane", "elroy" ],
  5. [ "homer", "marge", "bart" ],
  6. );
  7. print $AoA[2][2];
  8. bart

Now you should be very careful that the outer bracket type is a round one, that is, a parenthesis. That's because you're assigning to an @array, so you need parentheses. If you wanted there not to be an @AoA, but rather just a reference to it, you could do something more like this:

  1. # assign a reference to array of array references
  2. $ref_to_AoA = [
  3. [ "fred", "barney", "pebbles", "bambam", "dino", ],
  4. [ "homer", "bart", "marge", "maggie", ],
  5. [ "george", "jane", "elroy", "judy", ],
  6. ];
  7. print $ref_to_AoA->[2][2];

Notice that the outer bracket type has changed, and so our access syntax has also changed. That's because unlike C, in perl you can't freely interchange arrays and references thereto. $ref_to_AoA is a reference to an array, whereas @AoA is an array proper. Likewise, $AoA[2] is not an array, but an array ref. So how come you can write these:

  1. $AoA[2][2]
  2. $ref_to_AoA->[2][2]

instead of having to write these:

  1. $AoA[2]->[2]
  2. $ref_to_AoA->[2]->[2]

Well, that's because the rule is that on adjacent brackets only (whether square or curly), you are free to omit the pointer dereferencing arrow. But you cannot do so for the very first one if it's a scalar containing a reference, which means that $ref_to_AoA always needs it.

Growing Your Own

That's all well and good for declaration of a fixed data structure, but what if you wanted to add new elements on the fly, or build it up entirely from scratch?

First, let's look at reading it in from a file. This is something like adding a row at a time. We'll assume that there's a flat file in which each line is a row and each word an element. If you're trying to develop an @AoA array containing all these, here's the right way to do that:

  1. while (<>) {
  2. @tmp = split;
  3. push @AoA, [ @tmp ];
  4. }

You might also have loaded that from a function:

  1. for $i ( 1 .. 10 ) {
  2. $AoA[$i] = [ somefunc($i) ];
  3. }

Or you might have had a temporary variable sitting around with the array in it.

  1. for $i ( 1 .. 10 ) {
  2. @tmp = somefunc($i);
  3. $AoA[$i] = [ @tmp ];
  4. }

It's very important that you make sure to use the [] array reference constructor. That's because this will be very wrong:

  1. $AoA[$i] = @tmp;

You see, assigning a named array like that to a scalar just counts the number of elements in @tmp, which probably isn't what you want.

If you are running under use strict , you'll have to add some declarations to make it happy:

  1. use strict;
  2. my(@AoA, @tmp);
  3. while (<>) {
  4. @tmp = split;
  5. push @AoA, [ @tmp ];
  6. }

Of course, you don't need the temporary array to have a name at all:

  1. while (<>) {
  2. push @AoA, [ split ];
  3. }

You also don't have to use push(). You could just make a direct assignment if you knew where you wanted to put it:

  1. my (@AoA, $i, $line);
  2. for $i ( 0 .. 10 ) {
  3. $line = <>;
  4. $AoA[$i] = [ split ' ', $line ];
  5. }

or even just

  1. my (@AoA, $i);
  2. for $i ( 0 .. 10 ) {
  3. $AoA[$i] = [ split ' ', <> ];
  4. }

You should in general be leery of using functions that could potentially return lists in scalar context without explicitly stating such. This would be clearer to the casual reader:

  1. my (@AoA, $i);
  2. for $i ( 0 .. 10 ) {
  3. $AoA[$i] = [ split ' ', scalar(<>) ];
  4. }

If you wanted to have a $ref_to_AoA variable as a reference to an array, you'd have to do something like this:

  1. while (<>) {
  2. push @$ref_to_AoA, [ split ];
  3. }

Now you can add new rows. What about adding new columns? If you're dealing with just matrices, it's often easiest to use simple assignment:

  1. for $x (1 .. 10) {
  2. for $y (1 .. 10) {
  3. $AoA[$x][$y] = func($x, $y);
  4. }
  5. }
  6. for $x ( 3, 7, 9 ) {
  7. $AoA[$x][20] += func2($x);
  8. }

It doesn't matter whether those elements are already there or not: it'll gladly create them for you, setting intervening elements to undef as need be.

If you wanted just to append to a row, you'd have to do something a bit funnier looking:

  1. # add new columns to an existing row
  2. push @{ $AoA[0] }, "wilma", "betty";

Notice that I couldn't say just:

  1. push $AoA[0], "wilma", "betty"; # WRONG!

In fact, that wouldn't even compile. How come? Because the argument to push() must be a real array, not just a reference to such.

Access and Printing

Now it's time to print your data structure out. How are you going to do that? Well, if you want only one of the elements, it's trivial:

  1. print $AoA[0][0];

If you want to print the whole thing, though, you can't say

  1. print @AoA; # WRONG

because you'll get just references listed, and perl will never automatically dereference things for you. Instead, you have to roll yourself a loop or two. This prints the whole structure, using the shell-style for() construct to loop across the outer set of subscripts.

  1. for $aref ( @AoA ) {
  2. print "\t [ @$aref ],\n";
  3. }

If you wanted to keep track of subscripts, you might do this:

  1. for $i ( 0 .. $#AoA ) {
  2. print "\t elt $i is [ @{$AoA[$i]} ],\n";
  3. }

or maybe even this. Notice the inner loop.

  1. for $i ( 0 .. $#AoA ) {
  2. for $j ( 0 .. $#{$AoA[$i]} ) {
  3. print "elt $i $j is $AoA[$i][$j]\n";
  4. }
  5. }

As you can see, it's getting a bit complicated. That's why sometimes is easier to take a temporary on your way through:

  1. for $i ( 0 .. $#AoA ) {
  2. $aref = $AoA[$i];
  3. for $j ( 0 .. $#{$aref} ) {
  4. print "elt $i $j is $AoA[$i][$j]\n";
  5. }
  6. }

Hmm... that's still a bit ugly. How about this:

  1. for $i ( 0 .. $#AoA ) {
  2. $aref = $AoA[$i];
  3. $n = @$aref - 1;
  4. for $j ( 0 .. $n ) {
  5. print "elt $i $j is $AoA[$i][$j]\n";
  6. }
  7. }

Slices

If you want to get at a slice (part of a row) in a multidimensional array, you're going to have to do some fancy subscripting. That's because while we have a nice synonym for single elements via the pointer arrow for dereferencing, no such convenience exists for slices. (Remember, of course, that you can always write a loop to do a slice operation.)

Here's how to do one operation using a loop. We'll assume an @AoA variable as before.

  1. @part = ();
  2. $x = 4;
  3. for ($y = 7; $y < 13; $y++) {
  4. push @part, $AoA[$x][$y];
  5. }

That same loop could be replaced with a slice operation:

  1. @part = @{ $AoA[4] } [ 7..12 ];

but as you might well imagine, this is pretty rough on the reader.

Ah, but what if you wanted a two-dimensional slice, such as having $x run from 4..8 and $y run from 7 to 12? Hmm... here's the simple way:

  1. @newAoA = ();
  2. for ($startx = $x = 4; $x <= 8; $x++) {
  3. for ($starty = $y = 7; $y <= 12; $y++) {
  4. $newAoA[$x - $startx][$y - $starty] = $AoA[$x][$y];
  5. }
  6. }

We can reduce some of the looping through slices

  1. for ($x = 4; $x <= 8; $x++) {
  2. push @newAoA, [ @{ $AoA[$x] } [ 7..12 ] ];
  3. }

If you were into Schwartzian Transforms, you would probably have selected map for that

  1. @newAoA = map { [ @{ $AoA[$_] } [ 7..12 ] ] } 4 .. 8;

Although if your manager accused you of seeking job security (or rapid insecurity) through inscrutable code, it would be hard to argue. :-) If I were you, I'd put that in a function:

  1. @newAoA = splice_2D( \@AoA, 4 => 8, 7 => 12 );
  2. sub splice_2D {
  3. my $lrr = shift; # ref to array of array refs!
  4. my ($x_lo, $x_hi,
  5. $y_lo, $y_hi) = @_;
  6. return map {
  7. [ @{ $lrr->[$_] } [ $y_lo .. $y_hi ] ]
  8. } $x_lo .. $x_hi;
  9. }

SEE ALSO

perldata(1), perlref(1), perldsc(1)

AUTHOR

Tom Christiansen <tchrist@perl.com>

Last update: Thu Jun 4 16:16:23 MDT 1998