Perl version

Modules

  • ABCDE
  • FGHIL
  • MNOPS
  • TUX

perlfaq6

Perl 5 version 8.9 documentation
Recently read

perlfaq6

NAME

perlfaq6 - Regular Expressions ($Revision: 10126 $)

DESCRIPTION

This section is surprisingly small because the rest of the FAQ is littered with answers involving regular expressions. For example, decoding a URL and checking whether something is a number are handled with regular expressions, but those answers are found elsewhere in this document (in perlfaq9: "How do I decode or create those %-encodings on the web" and perlfaq4: "How do I determine whether a scalar is a number/whole/integer/float", to be precise).

How can I hope to use regular expressions without creating illegible and unmaintainable code?

Three techniques can make regular expressions maintainable and understandable.

  • Comments Outside the Regex

    Describe what you're doing and how you're doing it, using normal Perl comments.

    1. # turn the line into the first word, a colon, and the
    2. # number of characters on the rest of the line
    3. s/^(\w+)(.*)/ lc($1) . ":" . length($2) /meg;
  • Comments Inside the Regex

    The /x modifier causes whitespace to be ignored in a regex pattern (except in a character class), and also allows you to use normal comments there, too. As you can imagine, whitespace and comments help a lot.

    /x lets you turn this:

    1. s{<(?:[^>'"]*|".*?"|'.*?')+>}{}gs;

    into this:

    1. s{ < # opening angle bracket
    2. (?: # Non-backreffing grouping paren
    3. [^>'"] * # 0 or more things that are neither > nor ' nor "
    4. | # or else
    5. ".*?" # a section between double quotes (stingy match)
    6. | # or else
    7. '.*?' # a section between single quotes (stingy match)
    8. ) + # all occurring one or more times
    9. > # closing angle bracket
    10. }{}gsx; # replace with nothing, i.e. delete

    It's still not quite so clear as prose, but it is very useful for describing the meaning of each part of the pattern.

  • Different Delimiters

    While we normally think of patterns as being delimited with / characters, they can be delimited by almost any character. perlre describes this. For example, the s/// above uses braces as delimiters. Selecting another delimiter can avoid quoting the delimiter within the pattern:

    1. s/\/usr\/local/\/usr\/share/g; # bad delimiter choice
    2. s#/usr/local#/usr/share#g; # better

I'm having trouble matching over more than one line. What's wrong?

Either you don't have more than one line in the string you're looking at (probably), or else you aren't using the correct modifier(s) on your pattern (possibly).

There are many ways to get multiline data into a string. If you want it to happen automatically while reading input, you'll want to set $/ (probably to '' for paragraphs or undef for the whole file) to allow you to read more than one line at a time.

Read perlre to help you decide which of /s and /m (or both) you might want to use: /s allows dot to include newline, and /m allows caret and dollar to match next to a newline, not just at the end of the string. You do need to make sure that you've actually got a multiline string in there.

For example, this program detects duplicate words, even when they span line breaks (but not paragraph ones). For this example, we don't need /s because we aren't using dot in a regular expression that we want to cross line boundaries. Neither do we need /m because we aren't wanting caret or dollar to match at any point inside the record next to newlines. But it's imperative that $/ be set to something other than the default, or else we won't actually ever have a multiline record read in.

  1. $/ = ''; # read in more whole paragraph, not just one line
  2. while ( <> ) {
  3. while ( /\b([\w'-]+)(\s+\1)+\b/gi ) { # word starts alpha
  4. print "Duplicate $1 at paragraph $.\n";
  5. }
  6. }

Here's code that finds sentences that begin with "From " (which would be mangled by many mailers):

  1. $/ = ''; # read in more whole paragraph, not just one line
  2. while ( <> ) {
  3. while ( /^From /gm ) { # /m makes ^ match next to \n
  4. print "leading from in paragraph $.\n";
  5. }
  6. }

Here's code that finds everything between START and END in a paragraph:

  1. undef $/; # read in whole file, not just one line or paragraph
  2. while ( <> ) {
  3. while ( /START(.*?)END/sgm ) { # /s makes . cross line boundaries
  4. print "$1\n";
  5. }
  6. }

How can I pull out lines between two patterns that are themselves on different lines?

You can use Perl's somewhat exotic .. operator (documented in perlop):

  1. perl -ne 'print if /START/ .. /END/' file1 file2 ...

If you wanted text and not lines, you would use

  1. perl -0777 -ne 'print "$1\n" while /START(.*?)END/gs' file1 file2 ...

But if you want nested occurrences of START through END , you'll run up against the problem described in the question in this section on matching balanced text.

Here's another example of using .. :

  1. while (<>) {
  2. $in_header = 1 .. /^$/;
  3. $in_body = /^$/ .. eof;
  4. # now choose between them
  5. } continue {
  6. $. = 0 if eof; # fix $.
  7. }

I put a regular expression into $/ but it didn't work. What's wrong?

$/ has to be a string. You can use these examples if you really need to do this.

If you have File::Stream, this is easy.

  1. use File::Stream;
  2. my $stream = File::Stream->new(
  3. $filehandle,
  4. separator => qr/\s*,\s*/,
  5. );
  6. print "$_\n" while <$stream>;

If you don't have File::Stream, you have to do a little more work.

You can use the four argument form of sysread to continually add to a buffer. After you add to the buffer, you check if you have a complete line (using your regular expression).

  1. local $_ = "";
  2. while( sysread FH, $_, 8192, length ) {
  3. while( s/^((?s).*?)your_pattern/ ) {
  4. my $record = $1;
  5. # do stuff here.
  6. }
  7. }
  8. You can do the same thing with foreach and a match using the
  9. c flag and the \G anchor, if you do not mind your entire file
  10. being in memory at the end.
  11. local $_ = "";
  12. while( sysread FH, $_, 8192, length ) {
  13. foreach my $record ( m/\G((?s).*?)your_pattern/gc ) {
  14. # do stuff here.
  15. }
  16. substr( $_, 0, pos ) = "" if pos;
  17. }

How do I substitute case insensitively on the LHS while preserving case on the RHS?

Here's a lovely Perlish solution by Larry Rosler. It exploits properties of bitwise xor on ASCII strings.

  1. $_= "this is a TEsT case";
  2. $old = 'test';
  3. $new = 'success';
  4. s{(\Q$old\E)}
  5. { uc $new | (uc $1 ^ $1) .
  6. (uc(substr $1, -1) ^ substr $1, -1) x
  7. (length($new) - length $1)
  8. }egi;
  9. print;

And here it is as a subroutine, modeled after the above:

  1. sub preserve_case($$) {
  2. my ($old, $new) = @_;
  3. my $mask = uc $old ^ $old;
  4. uc $new | $mask .
  5. substr($mask, -1) x (length($new) - length($old))
  6. }
  7. $a = "this is a TEsT case";
  8. $a =~ s/(test)/preserve_case($1, "success")/egi;
  9. print "$a\n";

This prints:

  1. this is a SUcCESS case

As an alternative, to keep the case of the replacement word if it is longer than the original, you can use this code, by Jeff Pinyan:

  1. sub preserve_case {
  2. my ($from, $to) = @_;
  3. my ($lf, $lt) = map length, @_;
  4. if ($lt < $lf) { $from = substr $from, 0, $lt }
  5. else { $from .= substr $to, $lf }
  6. return uc $to | ($from ^ uc $from);
  7. }

This changes the sentence to "this is a SUcCess case."

Just to show that C programmers can write C in any programming language, if you prefer a more C-like solution, the following script makes the substitution have the same case, letter by letter, as the original. (It also happens to run about 240% slower than the Perlish solution runs.) If the substitution has more characters than the string being substituted, the case of the last character is used for the rest of the substitution.

  1. # Original by Nathan Torkington, massaged by Jeffrey Friedl
  2. #
  3. sub preserve_case($$)
  4. {
  5. my ($old, $new) = @_;
  6. my ($state) = 0; # 0 = no change; 1 = lc; 2 = uc
  7. my ($i, $oldlen, $newlen, $c) = (0, length($old), length($new));
  8. my ($len) = $oldlen < $newlen ? $oldlen : $newlen;
  9. for ($i = 0; $i < $len; $i++) {
  10. if ($c = substr($old, $i, 1), $c =~ /[\W\d_]/) {
  11. $state = 0;
  12. } elsif (lc $c eq $c) {
  13. substr($new, $i, 1) = lc(substr($new, $i, 1));
  14. $state = 1;
  15. } else {
  16. substr($new, $i, 1) = uc(substr($new, $i, 1));
  17. $state = 2;
  18. }
  19. }
  20. # finish up with any remaining new (for when new is longer than old)
  21. if ($newlen > $oldlen) {
  22. if ($state == 1) {
  23. substr($new, $oldlen) = lc(substr($new, $oldlen));
  24. } elsif ($state == 2) {
  25. substr($new, $oldlen) = uc(substr($new, $oldlen));
  26. }
  27. }
  28. return $new;
  29. }

How can I make \w match national character sets?

Put use locale; in your script. The \w character class is taken from the current locale.

See perllocale for details.

How can I match a locale-smart version of /[a-zA-Z]/ ?

You can use the POSIX character class syntax /[[:alpha:]]/ documented in perlre.

No matter which locale you are in, the alphabetic characters are the characters in \w without the digits and the underscore. As a regex, that looks like /[^\W\d_]/ . Its complement, the non-alphabetics, is then everything in \W along with the digits and the underscore, or /[\W\d_]/ .

How can I quote a variable to use in a regex?

The Perl parser will expand $variable and @variable references in regular expressions unless the delimiter is a single quote. Remember, too, that the right-hand side of a s/// substitution is considered a double-quoted string (see perlop for more details). Remember also that any regex special characters will be acted on unless you precede the substitution with \Q. Here's an example:

  1. $string = "Placido P. Octopus";
  2. $regex = "P.";
  3. $string =~ s/$regex/Polyp/;
  4. # $string is now "Polypacido P. Octopus"

Because . is special in regular expressions, and can match any single character, the regex P. here has matched the <Pl> in the original string.

To escape the special meaning of ., we use \Q :

  1. $string = "Placido P. Octopus";
  2. $regex = "P.";
  3. $string =~ s/\Q$regex/Polyp/;
  4. # $string is now "Placido Polyp Octopus"

The use of \Q causes the <.> in the regex to be treated as a regular character, so that P. matches a P followed by a dot.

What is /o really for?

(contributed by brian d foy)

The /o option for regular expressions (documented in perlop and perlreref) tells Perl to compile the regular expression only once. This is only useful when the pattern contains a variable. Perls 5.6 and later handle this automatically if the pattern does not change.

Since the match operator m//, the substitution operator s///, and the regular expression quoting operator qr// are double-quotish constructs, you can interpolate variables into the pattern. See the answer to "How can I quote a variable to use in a regex?" for more details.

This example takes a regular expression from the argument list and prints the lines of input that match it:

  1. my $pattern = shift @ARGV;
  2. while( <> ) {
  3. print if m/$pattern/;
  4. }

Versions of Perl prior to 5.6 would recompile the regular expression for each iteration, even if $pattern had not changed. The /o would prevent this by telling Perl to compile the pattern the first time, then reuse that for subsequent iterations:

  1. my $pattern = shift @ARGV;
  2. while( <> ) {
  3. print if m/$pattern/o; # useful for Perl < 5.6
  4. }

In versions 5.6 and later, Perl won't recompile the regular expression if the variable hasn't changed, so you probably don't need the /o option. It doesn't hurt, but it doesn't help either. If you want any version of Perl to compile the regular expression only once even if the variable changes (thus, only using its initial value), you still need the /o.

You can watch Perl's regular expression engine at work to verify for yourself if Perl is recompiling a regular expression. The use re 'debug' pragma (comes with Perl 5.005 and later) shows the details. With Perls before 5.6, you should see re reporting that its compiling the regular expression on each iteration. With Perl 5.6 or later, you should only see re report that for the first iteration.

  1. use re 'debug';
  2. $regex = 'Perl';
  3. foreach ( qw(Perl Java Ruby Python) ) {
  4. print STDERR "-" x 73, "\n";
  5. print STDERR "Trying $_...\n";
  6. print STDERR "\t$_ is good!\n" if m/$regex/;
  7. }

How do I use a regular expression to strip C style comments from a file?

While this actually can be done, it's much harder than you'd think. For example, this one-liner

  1. perl -0777 -pe 's{/\*.*?\*/}{}gs' foo.c

will work in many but not all cases. You see, it's too simple-minded for certain kinds of C programs, in particular, those with what appear to be comments in quoted strings. For that, you'd need something like this, created by Jeffrey Friedl and later modified by Fred Curtis.

  1. $/ = undef;
  2. $_ = <>;
  3. s#/\*[^*]*\*+([^/*][^*]*\*+)*/|("(\\.|[^"\\])*"|'(\\.|[^'\\])*'|.[^/"'\\]*)#defined $2 ? $2 : ""#gse;
  4. print;

This could, of course, be more legibly written with the /x modifier, adding whitespace and comments. Here it is expanded, courtesy of Fred Curtis.

  1. s{
  2. /\* ## Start of /* ... */ comment
  3. [^*]*\*+ ## Non-* followed by 1-or-more *'s
  4. (
  5. [^/*][^*]*\*+
  6. )* ## 0-or-more things which don't start with /
  7. ## but do end with '*'
  8. / ## End of /* ... */ comment
  9. | ## OR various things which aren't comments:
  10. (
  11. " ## Start of " ... " string
  12. (
  13. \\. ## Escaped char
  14. | ## OR
  15. [^"\\] ## Non "\
  16. )*
  17. " ## End of " ... " string
  18. | ## OR
  19. ' ## Start of ' ... ' string
  20. (
  21. \\. ## Escaped char
  22. | ## OR
  23. [^'\\] ## Non '\
  24. )*
  25. ' ## End of ' ... ' string
  26. | ## OR
  27. . ## Anything other char
  28. [^/"'\\]* ## Chars which doesn't start a comment, string or escape
  29. )
  30. }{defined $2 ? $2 : ""}gxse;

A slight modification also removes C++ comments, as long as they are not spread over multiple lines using a continuation character):

  1. s#/\*[^*]*\*+([^/*][^*]*\*+)*/|//[^\n]*|("(\\.|[^"\\])*"|'(\\.|[^'\\])*'|.[^/"'\\]*)#defined $2 ? $2 : ""#gse;

Can I use Perl regular expressions to match balanced text?

Historically, Perl regular expressions were not capable of matching balanced text. As of more recent versions of perl including 5.6.1 experimental features have been added that make it possible to do this. Look at the documentation for the (??{ }) construct in recent perlre manual pages to see an example of matching balanced parentheses. Be sure to take special notice of the warnings present in the manual before making use of this feature.

CPAN contains many modules that can be useful for matching text depending on the context. Damian Conway provides some useful patterns in Regexp::Common. The module Text::Balanced provides a general solution to this problem.

One of the common applications of balanced text matching is working with XML and HTML. There are many modules available that support these needs. Two examples are HTML::Parser and XML::Parser. There are many others.

An elaborate subroutine (for 7-bit ASCII only) to pull out balanced and possibly nested single chars, like ` and ', { and }, or ( and ) can be found in http://www.cpan.org/authors/id/TOMC/scripts/pull_quotes.gz .

The C::Scan module from CPAN also contains such subs for internal use, but they are undocumented.

What does it mean that regexes are greedy? How can I get around it?

Most people mean that greedy regexes match as much as they can. Technically speaking, it's actually the quantifiers (?, * , + , {} ) that are greedy rather than the whole pattern; Perl prefers local greed and immediate gratification to overall greed. To get non-greedy versions of the same quantifiers, use (?? , *? , +?, {}?).

An example:

  1. $s1 = $s2 = "I am very very cold";
  2. $s1 =~ s/ve.*y //; # I am cold
  3. $s2 =~ s/ve.*?y //; # I am very cold

Notice how the second substitution stopped matching as soon as it encountered "y ". The *? quantifier effectively tells the regular expression engine to find a match as quickly as possible and pass control on to whatever is next in line, like you would if you were playing hot potato.

How do I process each word on each line?

Use the split function:

  1. while (<>) {
  2. foreach $word ( split ) {
  3. # do something with $word here
  4. }
  5. }

Note that this isn't really a word in the English sense; it's just chunks of consecutive non-whitespace characters.

To work with only alphanumeric sequences (including underscores), you might consider

  1. while (<>) {
  2. foreach $word (m/(\w+)/g) {
  3. # do something with $word here
  4. }
  5. }

How can I print out a word-frequency or line-frequency summary?

To do this, you have to parse out each word in the input stream. We'll pretend that by word you mean chunk of alphabetics, hyphens, or apostrophes, rather than the non-whitespace chunk idea of a word given in the previous question:

  1. while (<>) {
  2. while ( /(\b[^\W_\d][\w'-]+\b)/g ) { # misses "`sheep'"
  3. $seen{$1}++;
  4. }
  5. }
  6. while ( ($word, $count) = each %seen ) {
  7. print "$count $word\n";
  8. }

If you wanted to do the same thing for lines, you wouldn't need a regular expression:

  1. while (<>) {
  2. $seen{$_}++;
  3. }
  4. while ( ($line, $count) = each %seen ) {
  5. print "$count $line";
  6. }

If you want these output in a sorted order, see perlfaq4: "How do I sort a hash (optionally by value instead of key)?".

How can I do approximate matching?

See the module String::Approx available from CPAN.

How do I efficiently match many regular expressions at once?

( contributed by brian d foy )

Avoid asking Perl to compile a regular expression every time you want to match it. In this example, perl must recompile the regular expression for every iteration of the foreach() loop since it has no way to know what $pattern will be.

  1. @patterns = qw( foo bar baz );
  2. LINE: while( <DATA> )
  3. {
  4. foreach $pattern ( @patterns )
  5. {
  6. if( /\b$pattern\b/i )
  7. {
  8. print;
  9. next LINE;
  10. }
  11. }
  12. }

The qr// operator showed up in perl 5.005. It compiles a regular expression, but doesn't apply it. When you use the pre-compiled version of the regex, perl does less work. In this example, I inserted a map() to turn each pattern into its pre-compiled form. The rest of the script is the same, but faster.

  1. @patterns = map { qr/\b$_\b/i } qw( foo bar baz );
  2. LINE: while( <> )
  3. {
  4. foreach $pattern ( @patterns )
  5. {
  6. print if /$pattern/i;
  7. next LINE;
  8. }
  9. }

In some cases, you may be able to make several patterns into a single regular expression. Beware of situations that require backtracking though.

  1. $regex = join '|', qw( foo bar baz );
  2. LINE: while( <> )
  3. {
  4. print if /\b(?:$regex)\b/i;
  5. }

For more details on regular expression efficiency, see Mastering Regular Expressions by Jeffrey Freidl. He explains how regular expressions engine work and why some patterns are surprisingly inefficient. Once you understand how perl applies regular expressions, you can tune them for individual situations.

Why don't word-boundary searches with \b work for me?

(contributed by brian d foy)

Ensure that you know what \b really does: it's the boundary between a word character, \w, and something that isn't a word character. That thing that isn't a word character might be \W, but it can also be the start or end of the string.

It's not (not!) the boundary between whitespace and non-whitespace, and it's not the stuff between words we use to create sentences.

In regex speak, a word boundary (\b) is a "zero width assertion", meaning that it doesn't represent a character in the string, but a condition at a certain position.

For the regular expression, /\bPerl\b/, there has to be a word boundary before the "P" and after the "l". As long as something other than a word character precedes the "P" and succeeds the "l", the pattern will match. These strings match /\bPerl\b/.

  1. "Perl" # no word char before P or after l
  2. "Perl " # same as previous (space is not a word char)
  3. "'Perl'" # the ' char is not a word char
  4. "Perl's" # no word char before P, non-word char after "l"

These strings do not match /\bPerl\b/.

  1. "Perl_" # _ is a word char!
  2. "Perler" # no word char before P, but one after l

You don't have to use \b to match words though. You can look for non-word characters surrounded by word characters. These strings match the pattern /\b'\b/.

  1. "don't" # the ' char is surrounded by "n" and "t"
  2. "qep'a'" # the ' char is surrounded by "p" and "a"

These strings do not match /\b'\b/.

  1. "foo'" # there is no word char after non-word '

You can also use the complement of \b, \B, to specify that there should not be a word boundary.

In the pattern /\Bam\B/, there must be a word character before the "a" and after the "m". These patterns match /\Bam\B/:

  1. "llama" # "am" surrounded by word chars
  2. "Samuel" # same

These strings do not match /\Bam\B/

  1. "Sam" # no word boundary before "a", but one after "m"
  2. "I am Sam" # "am" surrounded by non-word chars

Why does using $&, $`, or $' slow my program down?

(contributed by Anno Siegel)

Once Perl sees that you need one of these variables anywhere in the program, it provides them on each and every pattern match. That means that on every pattern match the entire string will be copied, part of it to $`, part to $&, and part to $'. Thus the penalty is most severe with long strings and patterns that match often. Avoid $&, $', and $` if you can, but if you can't, once you've used them at all, use them at will because you've already paid the price. Remember that some algorithms really appreciate them. As of the 5.005 release, the $& variable is no longer "expensive" the way the other two are.

Since Perl 5.6.1 the special variables @- and @+ can functionally replace $`, $& and $'. These arrays contain pointers to the beginning and end of each match (see perlvar for the full story), so they give you essentially the same information, but without the risk of excessive string copying.

What good is \G in a regular expression?

You use the \G anchor to start the next match on the same string where the last match left off. The regular expression engine cannot skip over any characters to find the next match with this anchor, so \G is similar to the beginning of string anchor, ^. The \G anchor is typically used with the g flag. It uses the value of pos() as the position to start the next match. As the match operator makes successive matches, it updates pos() with the position of the next character past the last match (or the first character of the next match, depending on how you like to look at it). Each string has its own pos() value.

Suppose you want to match all of consecutive pairs of digits in a string like "1122a44" and stop matching when you encounter non-digits. You want to match 11 and 22 but the letter <a> shows up between 22 and 44 and you want to stop at a . Simply matching pairs of digits skips over the a and still matches 44 .

  1. $_ = "1122a44";
  2. my @pairs = m/(\d\d)/g; # qw( 11 22 44 )

If you use the \G anchor, you force the match after 22 to start with the a . The regular expression cannot match there since it does not find a digit, so the next match fails and the match operator returns the pairs it already found.

  1. $_ = "1122a44";
  2. my @pairs = m/\G(\d\d)/g; # qw( 11 22 )

You can also use the \G anchor in scalar context. You still need the g flag.

  1. $_ = "1122a44";
  2. while( m/\G(\d\d)/g )
  3. {
  4. print "Found $1\n";
  5. }

After the match fails at the letter a , perl resets pos() and the next match on the same string starts at the beginning.

  1. $_ = "1122a44";
  2. while( m/\G(\d\d)/g )
  3. {
  4. print "Found $1\n";
  5. }
  6. print "Found $1 after while" if m/(\d\d)/g; # finds "11"

You can disable pos() resets on fail with the c flag, documented in perlop and perlreref. Subsequent matches start where the last successful match ended (the value of pos()) even if a match on the same string has failed in the meantime. In this case, the match after the while() loop starts at the a (where the last match stopped), and since it does not use any anchor it can skip over the a to find 44 .

  1. $_ = "1122a44";
  2. while( m/\G(\d\d)/gc )
  3. {
  4. print "Found $1\n";
  5. }
  6. print "Found $1 after while" if m/(\d\d)/g; # finds "44"

Typically you use the \G anchor with the c flag when you want to try a different match if one fails, such as in a tokenizer. Jeffrey Friedl offers this example which works in 5.004 or later.

  1. while (<>) {
  2. chomp;
  3. PARSER: {
  4. m/ \G( \d+\b )/gcx && do { print "number: $1\n"; redo; };
  5. m/ \G( \w+ )/gcx && do { print "word: $1\n"; redo; };
  6. m/ \G( \s+ )/gcx && do { print "space: $1\n"; redo; };
  7. m/ \G( [^\w\d]+ )/gcx && do { print "other: $1\n"; redo; };
  8. }
  9. }

For each line, the PARSER loop first tries to match a series of digits followed by a word boundary. This match has to start at the place the last match left off (or the beginning of the string on the first match). Since m/ \G( \d+\b )/gcx uses the c flag, if the string does not match that regular expression, perl does not reset pos() and the next match starts at the same position to try a different pattern.

Are Perl regexes DFAs or NFAs? Are they POSIX compliant?

While it's true that Perl's regular expressions resemble the DFAs (deterministic finite automata) of the egrep(1) program, they are in fact implemented as NFAs (non-deterministic finite automata) to allow backtracking and backreferencing. And they aren't POSIX-style either, because those guarantee worst-case behavior for all cases. (It seems that some people prefer guarantees of consistency, even when what's guaranteed is slowness.) See the book "Mastering Regular Expressions" (from O'Reilly) by Jeffrey Friedl for all the details you could ever hope to know on these matters (a full citation appears in perlfaq2).

What's wrong with using grep in a void context?

The problem is that grep builds a return list, regardless of the context. This means you're making Perl go to the trouble of building a list that you then just throw away. If the list is large, you waste both time and space. If your intent is to iterate over the list, then use a for loop for this purpose.

In perls older than 5.8.1, map suffers from this problem as well. But since 5.8.1, this has been fixed, and map is context aware - in void context, no lists are constructed.

How can I match strings with multibyte characters?

Starting from Perl 5.6 Perl has had some level of multibyte character support. Perl 5.8 or later is recommended. Supported multibyte character repertoires include Unicode, and legacy encodings through the Encode module. See perluniintro, perlunicode, and Encode.

If you are stuck with older Perls, you can do Unicode with the Unicode::String module, and character conversions using the Unicode::Map8 and Unicode::Map modules. If you are using Japanese encodings, you might try using the jperl 5.005_03.

Finally, the following set of approaches was offered by Jeffrey Friedl, whose article in issue #5 of The Perl Journal talks about this very matter.

Let's suppose you have some weird Martian encoding where pairs of ASCII uppercase letters encode single Martian letters (i.e. the two bytes "CV" make a single Martian letter, as do the two bytes "SG", "VS", "XX", etc.). Other bytes represent single characters, just like ASCII.

So, the string of Martian "I am CVSGXX!" uses 12 bytes to encode the nine characters 'I', ' ', 'a', 'm', ' ', 'CV', 'SG', 'XX', '!'.

Now, say you want to search for the single character /GX/ . Perl doesn't know about Martian, so it'll find the two bytes "GX" in the "I am CVSGXX!" string, even though that character isn't there: it just looks like it is because "SG" is next to "XX", but there's no real "GX". This is a big problem.

Here are a few ways, all painful, to deal with it:

  1. # Make sure adjacent "martian" bytes are no longer adjacent.
  2. $martian =~ s/([A-Z][A-Z])/ $1 /g;
  3. print "found GX!\n" if $martian =~ /GX/;

Or like this:

  1. @chars = $martian =~ m/([A-Z][A-Z]|[^A-Z])/g;
  2. # above is conceptually similar to: @chars = $text =~ m/(.)/g;
  3. #
  4. foreach $char (@chars) {
  5. print "found GX!\n", last if $char eq 'GX';
  6. }

Or like this:

  1. while ($martian =~ m/\G([A-Z][A-Z]|.)/gs) { # \G probably unneeded
  2. print "found GX!\n", last if $1 eq 'GX';
  3. }

Here's another, slightly less painful, way to do it from Benjamin Goldberg, who uses a zero-width negative look-behind assertion.

  1. print "found GX!\n" if $martian =~ m/
  2. (?<![A-Z])
  3. (?:[A-Z][A-Z])*?
  4. GX
  5. /x;

This succeeds if the "martian" character GX is in the string, and fails otherwise. If you don't like using (?<!), a zero-width negative look-behind assertion, you can replace (?<![A-Z]) with (?:^|[^A-Z]).

It does have the drawback of putting the wrong thing in $-[0] and $+[0], but this usually can be worked around.

How do I match a regular expression that's in a variable? ,

(contributed by brian d foy)

We don't have to hard-code patterns into the match operator (or anything else that works with regular expressions). We can put the pattern in a variable for later use.

The match operator is a double quote context, so you can interpolate your variable just like a double quoted string. In this case, you read the regular expression as user input and store it in $regex . Once you have the pattern in $regex , you use that variable in the match operator.

  1. chomp( my $regex = <STDIN> );
  2. if( $string =~ m/$regex/ ) { ... }

Any regular expression special characters in $regex are still special, and the pattern still has to be valid or Perl will complain. For instance, in this pattern there is an unpaired parenthesis.

  1. my $regex = "Unmatched ( paren";
  2. "Two parens to bind them all" =~ m/$regex/;

When Perl compiles the regular expression, it treats the parenthesis as the start of a memory match. When it doesn't find the closing parenthesis, it complains:

  1. Unmatched ( in regex; marked by <-- HERE in m/Unmatched ( <-- HERE paren/ at script line 3.

You can get around this in several ways depending on our situation. First, if you don't want any of the characters in the string to be special, you can escape them with quotemeta before you use the string.

  1. chomp( my $regex = <STDIN> );
  2. $regex = quotemeta( $regex );
  3. if( $string =~ m/$regex/ ) { ... }

You can also do this directly in the match operator using the \Q and \E sequences. The \Q tells Perl where to start escaping special characters, and the \E tells it where to stop (see perlop for more details).

  1. chomp( my $regex = <STDIN> );
  2. if( $string =~ m/\Q$regex\E/ ) { ... }

Alternately, you can use qr//, the regular expression quote operator (see perlop for more details). It quotes and perhaps compiles the pattern, and you can apply regular expression flags to the pattern.

  1. chomp( my $input = <STDIN> );
  2. my $regex = qr/$input/is;
  3. $string =~ m/$regex/ # same as m/$input/is;

You might also want to trap any errors by wrapping an eval block around the whole thing.

  1. chomp( my $input = <STDIN> );
  2. eval {
  3. if( $string =~ m/\Q$input\E/ ) { ... }
  4. };
  5. warn $@ if $@;

Or...

  1. my $regex = eval { qr/$input/is };
  2. if( defined $regex ) {
  3. $string =~ m/$regex/;
  4. }
  5. else {
  6. warn $@;
  7. }

REVISION

Revision: $Revision: 10126 $

Date: $Date: 2007-10-27 21:29:20 +0200 (Sat, 27 Oct 2007) $

See perlfaq for source control details and availability.

AUTHOR AND COPYRIGHT

Copyright (c) 1997-2007 Tom Christiansen, Nathan Torkington, and other authors as noted. All rights reserved.

This documentation is free; you can redistribute it and/or modify it under the same terms as Perl itself.

Irrespective of its distribution, all code examples in this file are hereby placed into the public domain. You are permitted and encouraged to use this code in your own programs for fun or for profit as you see fit. A simple comment in the code giving credit would be courteous but is not required.