Perl version

Modules

  • ABCDE
  • FGHIL
  • MNOPS
  • TUX

fields

Perl 5 version 20.0 documentation
Recently read

fields

NAME

fields - compile-time class fields

SYNOPSIS

  1. {
  2. package Foo;
  3. use fields qw(foo bar _Foo_private);
  4. sub new {
  5. my Foo $self = shift;
  6. unless (ref $self) {
  7. $self = fields::new($self);
  8. $self->{_Foo_private} = "this is Foo's secret";
  9. }
  10. $self->{foo} = 10;
  11. $self->{bar} = 20;
  12. return $self;
  13. }
  14. }
  15. my $var = Foo->new;
  16. $var->{foo} = 42;
  17. # this will generate a run-time error
  18. $var->{zap} = 42;
  19. # this will generate a compile-time error
  20. my Foo $foo = Foo->new;
  21. $foo->{zap} = 24;
  22. # subclassing
  23. {
  24. package Bar;
  25. use base 'Foo';
  26. use fields qw(baz _Bar_private); # not shared with Foo
  27. sub new {
  28. my $class = shift;
  29. my $self = fields::new($class);
  30. $self->SUPER::new(); # init base fields
  31. $self->{baz} = 10; # init own fields
  32. $self->{_Bar_private} = "this is Bar's secret";
  33. return $self;
  34. }
  35. }

DESCRIPTION

The fields pragma enables compile-time and run-time verified class fields.

NOTE: The current implementation keeps the declared fields in the %FIELDS hash of the calling package, but this may change in future versions. Do not update the %FIELDS hash directly, because it must be created at compile-time for it to be fully useful, as is done by this pragma.

If a typed lexical variable (my Class $var ) holding a reference is used to access a hash element and a package with the same name as the type has declared class fields using this pragma, then the hash key is verified at compile time. If the variables are not typed, access is only checked at run time.

The related base pragma will combine fields from base classes and any fields declared using the fields pragma. This enables field inheritance to work properly. Inherited fields can be overridden but will generate a warning if warnings are enabled.

Only valid for Perl 5.8.x and earlier: Field names that start with an underscore character are made private to the class and are not visible to subclasses.

Also, in Perl 5.8.x and earlier, this pragma uses pseudo-hashes, the effect being that you can have objects with named fields which are as compact and as fast arrays to access, as long as the objects are accessed through properly typed variables.

The following functions are supported:

  • new

    fields::new() creates and blesses a hash comprised of the fields declared using the fields pragma into the specified class. It is the recommended way to construct a fields-based object.

    This makes it possible to write a constructor like this:

    1. package Critter::Sounds;
    2. use fields qw(cat dog bird);
    3. sub new {
    4. my $self = shift;
    5. $self = fields::new($self) unless ref $self;
    6. $self->{cat} = 'meow'; # scalar element
    7. @$self{'dog','bird'} = ('bark','tweet'); # slice
    8. return $self;
    9. }
  • phash

    This function only works in Perl 5.8.x and earlier. Pseudo-hashes were removed from Perl as of 5.10. Consider using restricted hashes or fields::new() instead (which itself uses restricted hashes under 5.10+). See Hash::Util. Using fields::phash() under 5.10 or higher will cause an error.

    fields::phash() can be used to create and initialize a plain (unblessed) pseudo-hash. This function should always be used instead of creating pseudo-hashes directly.

    If the first argument is a reference to an array, the pseudo-hash will be created with keys from that array. If a second argument is supplied, it must also be a reference to an array whose elements will be used as the values. If the second array contains less elements than the first, the trailing elements of the pseudo-hash will not be initialized. This makes it particularly useful for creating a pseudo-hash from subroutine arguments:

    1. sub dogtag {
    2. my $tag = fields::phash([qw(name rank ser_num)], [@_]);
    3. }

    fields::phash() also accepts a list of key-value pairs that will be used to construct the pseudo hash. Examples:

    1. my $tag = fields::phash(name => "Joe",
    2. rank => "captain",
    3. ser_num => 42);
    4. my $pseudohash = fields::phash(%args);

SEE ALSO

base, Hash::Util