Perl 5 version 24.0 documentation



  1. use warnings;
  2. no warnings;
  3. use warnings "all";
  4. no warnings "all";
  5. use warnings::register;
  6. if (warnings::enabled()) {
  7. warnings::warn("some warning");
  8. }
  9. if (warnings::enabled("void")) {
  10. warnings::warn("void", "some warning");
  11. }
  12. if (warnings::enabled($object)) {
  13. warnings::warn($object, "some warning");
  14. }
  15. warnings::warnif("some warning");
  16. warnings::warnif("void", "some warning");
  17. warnings::warnif($object, "some warning");


The warnings pragma gives control over which warnings are enabled in which parts of a Perl program. It's a more flexible alternative for both the command line flag -w and the equivalent Perl variable, $^W .

This pragma works just like the strict pragma. This means that the scope of the warning pragma is limited to the enclosing block. It also means that the pragma setting will not leak across files (via use, require or do). This allows authors to independently define the degree of warning checks that will be applied to their module.

By default, optional warnings are disabled, so any legacy code that doesn't attempt to control the warnings will work unchanged.

All warnings are enabled in a block by either of these:

  1. use warnings;
  2. use warnings 'all';

Similarly all warnings are disabled in a block by either of these:

  1. no warnings;
  2. no warnings 'all';

For example, consider the code below:

  1. use warnings;
  2. my @a;
  3. {
  4. no warnings;
  5. my $b = @a[0];
  6. }
  7. my $c = @a[0];

The code in the enclosing block has warnings enabled, but the inner block has them disabled. In this case that means the assignment to the scalar $c will trip the "Scalar value @a[0] better written as $a[0]" warning, but the assignment to the scalar $b will not.

Default Warnings and Optional Warnings

Before the introduction of lexical warnings, Perl had two classes of warnings: mandatory and optional.

As its name suggests, if your code tripped a mandatory warning, you would get a warning whether you wanted it or not. For example, the code below would always produce an "isn't numeric" warning about the "2:".

  1. my $a = "2:" + 3;

With the introduction of lexical warnings, mandatory warnings now become default warnings. The difference is that although the previously mandatory warnings are still enabled by default, they can then be subsequently enabled or disabled with the lexical warning pragma. For example, in the code below, an "isn't numeric" warning will only be reported for the $a variable.

  1. my $a = "2:" + 3;
  2. no warnings;
  3. my $b = "2:" + 3;

Note that neither the -w flag or the $^W can be used to disable/enable default warnings. They are still mandatory in this case.

What's wrong with -w and $^W

Although very useful, the big problem with using -w on the command line to enable warnings is that it is all or nothing. Take the typical scenario when you are writing a Perl program. Parts of the code you will write yourself, but it's very likely that you will make use of pre-written Perl modules. If you use the -w flag in this case, you end up enabling warnings in pieces of code that you haven't written.

Similarly, using $^W to either disable or enable blocks of code is fundamentally flawed. For a start, say you want to disable warnings in a block of code. You might expect this to be enough to do the trick:

  1. {
  2. local ($^W) = 0;
  3. my $a =+ 2;
  4. my $b; chop $b;
  5. }

When this code is run with the -w flag, a warning will be produced for the $a line: "Reversed += operator" .

The problem is that Perl has both compile-time and run-time warnings. To disable compile-time warnings you need to rewrite the code like this:

  1. {
  2. BEGIN { $^W = 0 }
  3. my $a =+ 2;
  4. my $b; chop $b;
  5. }

The other big problem with $^W is the way you can inadvertently change the warning setting in unexpected places in your code. For example, when the code below is run (without the -w flag), the second call to doit will trip a "Use of uninitialized value" warning, whereas the first will not.

  1. sub doit
  2. {
  3. my $b; chop $b;
  4. }
  5. doit();
  6. {
  7. local ($^W) = 1;
  8. doit()
  9. }

This is a side-effect of $^W being dynamically scoped.

Lexical warnings get around these limitations by allowing finer control over where warnings can or can't be tripped.

Controlling Warnings from the Command Line

There are three Command Line flags that can be used to control when warnings are (or aren't) produced:

  • -w

    This is the existing flag. If the lexical warnings pragma is not used in any of you code, or any of the modules that you use, this flag will enable warnings everywhere. See Backward Compatibility for details of how this flag interacts with lexical warnings.

  • -W

    If the -W flag is used on the command line, it will enable all warnings throughout the program regardless of whether warnings were disabled locally using no warnings or $^W =0 . This includes all files that get included via use, require or do. Think of it as the Perl equivalent of the "lint" command.

  • -X

    Does the exact opposite to the -W flag, i.e. it disables all warnings.

Backward Compatibility

If you are used to working with a version of Perl prior to the introduction of lexically scoped warnings, or have code that uses both lexical warnings and $^W , this section will describe how they interact.

How Lexical Warnings interact with -w/$^W :

  • If none of the three command line flags (-w, -W or -X) that control warnings is used and neither $^W nor the warnings pragma are used, then default warnings will be enabled and optional warnings disabled. This means that legacy code that doesn't attempt to control the warnings will work unchanged.

  • The -w flag just sets the global $^W variable as in 5.005. This means that any legacy code that currently relies on manipulating $^W to control warning behavior will still work as is.

  • Apart from now being a boolean, the $^W variable operates in exactly the same horrible uncontrolled global way, except that it cannot disable/enable default warnings.

  • If a piece of code is under the control of the warnings pragma, both the $^W variable and the -w flag will be ignored for the scope of the lexical warning.

  • The only way to override a lexical warnings setting is with the -W or -X command line flags.

  • The combined effect of 3 & 4 is that it will allow code which uses the warnings pragma to control the warning behavior of $^W-type code (using a local $^W=0 ) if it really wants to, but not vice-versa.

    Category Hierarchy

    A hierarchy of "categories" have been defined to allow groups of warnings to be enabled/disabled in isolation.

    The current hierarchy is:

    1. all -+
    2. |
    3. +- closure
    4. |
    5. +- deprecated
    6. |
    7. +- exiting
    8. |
    9. +- experimental --+
    10. | |
    11. | +- experimental::bitwise
    12. | |
    13. | +- experimental::const_attr
    14. | |
    15. | +- experimental::lexical_subs
    16. | |
    17. | +- experimental::postderef
    18. | |
    19. | +- experimental::re_strict
    20. | |
    21. | +- experimental::refaliasing
    22. | |
    23. | +- experimental::regex_sets
    24. | |
    25. | +- experimental::signatures
    26. | |
    27. | +- experimental::smartmatch
    28. | |
    29. | +- experimental::win32_perlio
    30. |
    31. +- glob
    32. |
    33. +- imprecision
    34. |
    35. +- io ------------+
    36. | |
    37. | +- closed
    38. | |
    39. | +- exec
    40. | |
    41. | +- layer
    42. | |
    43. | +- newline
    44. | |
    45. | +- pipe
    46. | |
    47. | +- syscalls
    48. | |
    49. | +- unopened
    50. |
    51. +- locale
    52. |
    53. +- misc
    54. |
    55. +- missing
    56. |
    57. +- numeric
    58. |
    59. +- once
    60. |
    61. +- overflow
    62. |
    63. +- pack
    64. |
    65. +- portable
    66. |
    67. +- recursion
    68. |
    69. +- redefine
    70. |
    71. +- redundant
    72. |
    73. +- regexp
    74. |
    75. +- severe --------+
    76. | |
    77. | +- debugging
    78. | |
    79. | +- inplace
    80. | |
    81. | +- internal
    82. | |
    83. | +- malloc
    84. |
    85. +- signal
    86. |
    87. +- substr
    88. |
    89. +- syntax --------+
    90. | |
    91. | +- ambiguous
    92. | |
    93. | +- bareword
    94. | |
    95. | +- digit
    96. | |
    97. | +- illegalproto
    98. | |
    99. | +- parenthesis
    100. | |
    101. | +- precedence
    102. | |
    103. | +- printf
    104. | |
    105. | +- prototype
    106. | |
    107. | +- qw
    108. | |
    109. | +- reserved
    110. | |
    111. | +- semicolon
    112. |
    113. +- taint
    114. |
    115. +- threads
    116. |
    117. +- uninitialized
    118. |
    119. +- unpack
    120. |
    121. +- untie
    122. |
    123. +- utf8 ----------+
    124. | |
    125. | +- non_unicode
    126. | |
    127. | +- nonchar
    128. | |
    129. | +- surrogate
    130. |
    131. +- void

    Just like the "strict" pragma any of these categories can be combined

    1. use warnings qw(void redefine);
    2. no warnings qw(io syntax untie);

    Also like the "strict" pragma, if there is more than one instance of the warnings pragma in a given scope the cumulative effect is additive.

    1. use warnings qw(void); # only "void" warnings enabled
    2. ...
    3. use warnings qw(io); # only "void" & "io" warnings enabled
    4. ...
    5. no warnings qw(void); # only "io" warnings enabled

    To determine which category a specific warning has been assigned to see perldiag.

    Note: Before Perl 5.8.0, the lexical warnings category "deprecated" was a sub-category of the "syntax" category. It is now a top-level category in its own right.

    Note: Before 5.21.0, the "missing" lexical warnings category was internally defined to be the same as the "uninitialized" category. It is now a top-level category in its own right.

    Fatal Warnings

    The presence of the word "FATAL" in the category list will escalate warnings in those categories into fatal errors in that lexical scope.

    NOTE: FATAL warnings should be used with care, particularly FATAL => 'all' .

    Libraries using warnings::warn for custom warning categories generally don't expect warnings::warn to be fatal and can wind up in an unexpected state as a result. For XS modules issuing categorized warnings, such unanticipated exceptions could also expose memory leak bugs.

    Moreover, the Perl interpreter itself has had serious bugs involving fatalized warnings. For a summary of resolved and unresolved problems as of January 2015, please see this perl5-porters post.

    While some developers find fatalizing some warnings to be a useful defensive programming technique, using FATAL => 'all' to fatalize all possible warning categories -- including custom ones -- is particularly risky. Therefore, the use of FATAL => 'all' is discouraged.

    The strictures module on CPAN offers one example of a warnings subset that the module's authors believe is relatively safe to fatalize.

    NOTE: users of FATAL warnings, especially those using FATAL => 'all' , should be fully aware that they are risking future portability of their programs by doing so. Perl makes absolutely no commitments to not introduce new warnings or warnings categories in the future; indeed, we explicitly reserve the right to do so. Code that may not warn now may warn in a future release of Perl if the Perl5 development team deems it in the best interests of the community to do so. Should code using FATAL warnings break due to the introduction of a new warning we will NOT consider it an incompatible change. Users of FATAL warnings should take special caution during upgrades to check to see if their code triggers any new warnings and should pay particular attention to the fine print of the documentation of the features they use to ensure they do not exploit features that are documented as risky, deprecated, or unspecified, or where the documentation says "so don't do that", or anything with the same sense and spirit. Use of such features in combination with FATAL warnings is ENTIRELY AT THE USER'S RISK.

    The following documentation describes how to use FATAL warnings but the perl5 porters strongly recommend that you understand the risks before doing so, especially for library code intended for use by others, as there is no way for downstream users to change the choice of fatal categories.

    In the code below, the use of time, length and join can all produce a "Useless use of xxx in void context" warning.

    1. use warnings;
    2. time;
    3. {
    4. use warnings FATAL => qw(void);
    5. length "abc";
    6. }
    7. join "", 1,2,3;
    8. print "done\n";

    When run it produces this output

    1. Useless use of time in void context at fatal line 3.
    2. Useless use of length in void context at fatal line 7.

    The scope where length is used has escalated the void warnings category into a fatal error, so the program terminates immediately when it encounters the warning.

    To explicitly turn off a "FATAL" warning you just disable the warning it is associated with. So, for example, to disable the "void" warning in the example above, either of these will do the trick:

    1. no warnings qw(void);
    2. no warnings FATAL => qw(void);

    If you want to downgrade a warning that has been escalated into a fatal error back to a normal warning, you can use the "NONFATAL" keyword. For example, the code below will promote all warnings into fatal errors, except for those in the "syntax" category.

    1. use warnings FATAL => 'all', NONFATAL => 'syntax';

    As of Perl 5.20, instead of use warnings FATAL => 'all'; you can use:

    1. use v5.20; # Perl 5.20 or greater is required for the following
    2. use warnings 'FATAL'; # short form of "use warnings FATAL => 'all';"

    If you want your program to be compatible with versions of Perl before 5.20, you must use use warnings FATAL => 'all'; instead. (In previous versions of Perl, the behavior of the statements use warnings 'FATAL'; , use warnings 'NONFATAL'; and no warnings 'FATAL'; was unspecified; they did not behave as if they included the => 'all' portion. As of 5.20, they do.)

    Reporting Warnings from a Module

    The warnings pragma provides a number of functions that are useful for module authors. These are used when you want to report a module-specific warning to a calling module has enabled warnings via the warnings pragma.

    Consider the module MyMod::Abc below.

    1. package MyMod::Abc;
    2. use warnings::register;
    3. sub open {
    4. my $path = shift;
    5. if ($path !~ m#^/#) {
    6. warnings::warn("changing relative path to /var/abc")
    7. if warnings::enabled();
    8. $path = "/var/abc/$path";
    9. }
    10. }
    11. 1;

    The call to warnings::register will create a new warnings category called "MyMod::Abc", i.e. the new category name matches the current package name. The open function in the module will display a warning message if it gets given a relative path as a parameter. This warnings will only be displayed if the code that uses MyMod::Abc has actually enabled them with the warnings pragma like below.

    1. use MyMod::Abc;
    2. use warnings 'MyMod::Abc';
    3. ...
    4. abc::open("../fred.txt");

    It is also possible to test whether the pre-defined warnings categories are set in the calling module with the warnings::enabled function. Consider this snippet of code:

    1. package MyMod::Abc;
    2. sub open {
    3. if (warnings::enabled("deprecated")) {
    4. warnings::warn("deprecated",
    5. "open is deprecated, use new instead");
    6. }
    7. new(@_);
    8. }
    9. sub new
    10. ...
    11. 1;

    The function open has been deprecated, so code has been included to display a warning message whenever the calling module has (at least) the "deprecated" warnings category enabled. Something like this, say.

    1. use warnings 'deprecated';
    2. use MyMod::Abc;
    3. ...
    4. MyMod::Abc::open($filename);

    Either the warnings::warn or warnings::warnif function should be used to actually display the warnings message. This is because they can make use of the feature that allows warnings to be escalated into fatal errors. So in this case

    1. use MyMod::Abc;
    2. use warnings FATAL => 'MyMod::Abc';
    3. ...
    4. MyMod::Abc::open('../fred.txt');

    the warnings::warnif function will detect this and die after displaying the warning message.

    The three warnings functions, warnings::warn , warnings::warnif and warnings::enabled can optionally take an object reference in place of a category name. In this case the functions will use the class name of the object as the warnings category.

    Consider this example:

    1. package Original;
    2. no warnings;
    3. use warnings::register;
    4. sub new
    5. {
    6. my $class = shift;
    7. bless [], $class;
    8. }
    9. sub check
    10. {
    11. my $self = shift;
    12. my $value = shift;
    13. if ($value % 2 && warnings::enabled($self))
    14. { warnings::warn($self, "Odd numbers are unsafe") }
    15. }
    16. sub doit
    17. {
    18. my $self = shift;
    19. my $value = shift;
    20. $self->check($value);
    21. # ...
    22. }
    23. 1;
    24. package Derived;
    25. use warnings::register;
    26. use Original;
    27. our @ISA = qw( Original );
    28. sub new
    29. {
    30. my $class = shift;
    31. bless [], $class;
    32. }
    33. 1;

    The code below makes use of both modules, but it only enables warnings from Derived .

    1. use Original;
    2. use Derived;
    3. use warnings 'Derived';
    4. my $a = Original->new();
    5. $a->doit(1);
    6. my $b = Derived->new();
    7. $a->doit(1);

    When this code is run only the Derived object, $b , will generate a warning.

    1. Odd numbers are unsafe at line 7

    Notice also that the warning is reported at the line where the object is first used.

    When registering new categories of warning, you can supply more names to warnings::register like this:

    1. package MyModule;
    2. use warnings::register qw(format precision);
    3. ...
    4. warnings::warnif('MyModule::format', '...');


    • use warnings::register

      Creates a new warnings category with the same name as the package where the call to the pragma is used.

    • warnings::enabled()

      Use the warnings category with the same name as the current package.

      Return TRUE if that warnings category is enabled in the calling module. Otherwise returns FALSE.

    • warnings::enabled($category)

      Return TRUE if the warnings category, $category , is enabled in the calling module. Otherwise returns FALSE.

    • warnings::enabled($object)

      Use the name of the class for the object reference, $object , as the warnings category.

      Return TRUE if that warnings category is enabled in the first scope where the object is used. Otherwise returns FALSE.

    • warnings::fatal_enabled()

      Return TRUE if the warnings category with the same name as the current package has been set to FATAL in the calling module. Otherwise returns FALSE.

    • warnings::fatal_enabled($category)

      Return TRUE if the warnings category $category has been set to FATAL in the calling module. Otherwise returns FALSE.

    • warnings::fatal_enabled($object)

      Use the name of the class for the object reference, $object , as the warnings category.

      Return TRUE if that warnings category has been set to FATAL in the first scope where the object is used. Otherwise returns FALSE.

    • warnings::warn($message)

      Print $message to STDERR.

      Use the warnings category with the same name as the current package.

      If that warnings category has been set to "FATAL" in the calling module then die. Otherwise return.

    • warnings::warn($category, $message)

      Print $message to STDERR.

      If the warnings category, $category , has been set to "FATAL" in the calling module then die. Otherwise return.

    • warnings::warn($object, $message)

      Print $message to STDERR.

      Use the name of the class for the object reference, $object , as the warnings category.

      If that warnings category has been set to "FATAL" in the scope where $object is first used then die. Otherwise return.

    • warnings::warnif($message)

      Equivalent to:

      1. if (warnings::enabled())
      2. { warnings::warn($message) }
    • warnings::warnif($category, $message)

      Equivalent to:

      1. if (warnings::enabled($category))
      2. { warnings::warn($category, $message) }
    • warnings::warnif($object, $message)

      Equivalent to:

      1. if (warnings::enabled($object))
      2. { warnings::warn($object, $message) }
    • warnings::register_categories(@names)

      This registers warning categories for the given names and is primarily for use by the warnings::register pragma.

    See also Pragmatic Modules in perlmodlib and perldiag.